Windows 初心者がやってみた AutoHotkey 設定. ショートカット/ホットキー/キーリマップ/GUI など

/*
===================================
ショートカット
===================================
*/
/*
 Esc で IMEオフ + Esc 送出
 Google IME の設定で F12 に「IME無効化」を割り当てている
 $ は Esc の無限ループ防止のため
*/
$Esc::Send '{F12}{Esc}'
; mac 風にスクリーンショット
^+4::Send '{PrintScreen}'

/*
title: Window Titles https://ahkscript.github.io/ja/docs/v2/misc/WinTitle.htm
cmd: アプリを起動するためのコマンド
*/

switch_app_status(title, cmd:="") {
	if WinExist(title) {
		if WinActive() {
			WinMoveBottom
			if WinExist( , , title) {
				WinActivate ; `title` 以外の見つかったウインドウがアクティブになる
			}
		} else {
			WinMoveTop
			WinActivate
		}
	} else {
        cmd := String(cmd)
        if (cmd != "") {
		    Run cmd
        } else {
            MsgBox "このアプリケーションは起動していません"
        }
	}
}

/*
===================================
ホットキー
アプリをトグルでアクティブ/インアクティブ
アプリが起動していない場合は起動
===================================
*/

/*
Ctrl + Enter Windows Terminal
*/
^Enter::
{
	switch_app_status("ahk_exe WindowsTerminal.exe", "wt -p Ubuntu")
}


/*
Ctrl + \ エクスプローラー
*/
^\::
{
	switch_app_status("ahk_class CabinetWClass", "explorer")
}


/*
Ctrl + 0 VSCode
*/
^0::
{
	switch_app_status("ahk_exe Code.exe", "Code")
}

/*
===================================
GUI
アプリをトグルでアクティブ/インアクティブ
アプリが起動していない場合は起動
起動コマンドが指定されていない場合は
アプリ未起動時は button が disabled になる
===================================
*/
a_outlook(*) {
    switch_app_status("ahk_exe outlook.exe")
    WinClose("Select an app")
}
a_teams(*) {
    switch_app_status("ahk_exe ms-teams.exe")
    WinClose("Select an app")
}
a_edge(*) {
    switch_app_status("ahk_exe msedge.exe")
    WinClose("Select an app")
}
a_code(*) {
    switch_app_status("ahk_exe Code.exe", "code")
    WinClose("Select an app")
}
exit_gui(*) {
    If WinExist("Select an app") {
		WinClose
    }
}


/*
Alt 2連打で GUI を起動
Interval <= 400ms
*/
Alt::
{
    if (A_ThisHotkey == A_PriorHotkey && A_TimeSincePriorHotkey <= 400) {
        If WinExist("Select an app") {
            WinActivate
            return
        }
        MyGui := Gui(, "Select an app")
        MyGui.SetFont("s14")
        apps := [
            Map("app_name", "Outlook", "func", a_outlook, "win_title", "ahk_exe outlook.exe"),
            Map("app_name", "Teams", "func", a_teams, "win_title", "ahk_exe ms-teams.exe"),
            Map("app_name", "Edge", "func", a_edge, "win_title", "ahk_exe msedge.exe"),
            Map("app_name", "VSCode", "func", a_code, "win_title", "ahk_exe Code.exe")
        ]
        for (v in apps) {
            opt_disabled := ""
            name_disabled := ""
            if not WinExist(v["win_title"]) {
                opt_disabled := "disabled "
                name_disabled := " (not started)"
            }
            MyGui.Add("Button", opt_disabled "W250", v["app_name"] name_disabled).OnEvent("click", v["func"])
        }
        MyGui.OnEvent("Escape", exit_gui)
        MyGui.show()
    }
}